Arduino Nano PI Main Discussion

[Olly]

Thanks Martin,
Loads of good info to get going with.
Much appreciated

[Qiaozhi]

After following the book to the letter I'm happy to report that my Nano PI is working very well indeed.
Many thanks Qiaozhi for your excellent design and well written, easy to follow instructions and guidelines.
Also many thanks to Silverdog for providing the high quality PCB's with such a short turn-around time; I'm most grateful.

Now that everything is working correctly I'd like to make it look a little bit more professional and was wondering where folks in the UK source such things as detector stems and coil housings at a reasonable price?

Thanks for the good feedback.

It's actually Don Bowers who makes the coil shells in America, not dbanner. His website is here: https://sites.google.com/site/dbcoilshells/

As Martin says, Joan Allen can supply shafts from several manufacturers: https://joanallen.co.uk/accessories/shafts.html
There's also Spin-a-disc: https://spinadiscmetaldetectors.com/...afts-and-stems
and Pepsi Piros Metal Detectors: https://www.metaldetectors-pepsi.co....ssories/Shafts

It may even be less expensive to buy a cheap Chinese detector from ebay and use that as a source of parts.

You might want to try this site for coil shells: https://sites.google.com/site/mmcoilshells/home
I've never used them, so it would interesting to know if you have any luck.

[MartinB]

Thanks for the good feedback.

It's actually Don Bowers who makes the coil shells in America, not dbanner. His website is here: https://sites.google.com/site/dbcoilshells/

As Martin says, Joan Allen can supply shafts from several manufacturers: https://joanallen.co.uk/accessories/shafts.html
There's also Spin-a-disc: https://spinadiscmetaldetectors.com/...afts-and-stems
and Pepsi Piros Metal Detectors: https://www.metaldetectors-pepsi.co....ssories/Shafts

It may even be less expensive to buy a cheap Chinese detector from ebay and use that as a source of parts.

You might want to try this site for coil shells: https://sites.google.com/site/mmcoilshells/home
I've never used them, so it would interesting to know if you have any luck.

Hi George
Thanks for correcting me
Sorry for the error Mr Bowers.

[gallico58]

Glad to hear that you achieved a good result.


I'm not sure if that would make any difference, as noise will only be a problem if they are being used. But you could try setting the unused analog pins as digital outputs, and then drive them with a permanent LOW.

For example:
pinMode(A1, OUTPUT);
digitalWrite(A1, LOW);

Alternatively, you could simply pull the analog inputs HIGH using the internal pull-up resistor.

For example:
pinMode(A1, INPUT_PULLUP);

Arduino Nano Pi works, only a small problem I ask you
The main clock frequency that we find at PIN D8 has small phase movements detected with oscilloscope that translate into rhythmic disorders by adjusting the threshold and the main sampling
Power is stable and regular tensions, the problem seems to be the internal management of Arduino system clocks or software.
The same problem detected on an Arduino one programmed alone without external components.

[Teleno]

Arduino Nano Pi works, only a small problem I ask you
The main clock frequency that we find at PIN D8 has small phase movements detected with oscilloscope that translate into rhythmic disorders by adjusting the threshold and the main sampling
Power is stable and regular tensions, the problem seems to be the internal management of Arduino system clocks or software.
The same problem detected on an Arduino one programmed alone without external components.

I think the problem is in these lines:

[I]    delayVal = analogRead(delayPin);                   // Read the delay pot[/I]
[I]    mainDelay = defMainDelay + delayVal * clockCycle;  // Offset main sample delay[/I]

The sample delay pot is 10K, the ADC resolution is 10 bits (1024 steps).
This means a change in 9,7 Ohms (0.1%) will alter the timing by 1 clock cycle. Such a small resistance change can be caused by the pot itself without touching it and/or the ADC conversion noise itself, since it only needs one bit of error to cause pulse jitter. That's where the observed phase noise in the pulse comes from.

To avoid this, a change in delayVal larger than 1 bit should be required to alter the offset.

In the whole range of the ADC, delayVal * clockCycle gives a maximum offset of 63,4 us. If such a long offset is not needed, the pot/ADC noise can be reduced or eliminated by reducing the resolution. For example:

    [I]mainDelay = defMainDelay + (delayVal >> 1) * clockCycle;  // Offset main sample delay[/I]

Now it takes 2 bits to move the offset. Halving the resolution doubles the minimum resistance change to 19.4 Ohms (0.2%). Still too low anyway but check it out, it the pulse should be more stable. The maximum achievable offset is halved to 32 us.

It can be reduced further to about 40 Ohms (0.4%) if you don't need an offset larger than 16us:

    [I]mainDelay = defMainDelay + (delayVal >> 2) * clockCycle; // Offset main sample delay[/I]

Now it takes 4 bits to move the offset.


Alternatively the delayVal can be averaged or low pass filtered using a IIR filter, but that complicates the code a bit.

This can be of interest: Reading very small adjustments from a potentiometer accurately?


Another option is to add hysteresis:

[I]    word potRead = 0;
   ...
   ...
   potRead = analogRead(delayPin);                   // Read the delay pot
[/I]   [I]if ([/I][I]potRead [/I][I]> (delayVal + 16)) delayVal = [/I][I]potRead [/I][I]- 16;
   else if [/I][I]([/I][I]potRead [/I][I]< (delayVal  - 16)) delayVal = [/I][I]potRead [/I][I]+ 16;[/I]
[I]   mainDelay = defMainDelay + delayVal * clockCycle;  // Offset main sample delay[/I]

this will require 4 bits in order to move the offset one clock cycle up or down while maitaining the maximum offset at 63,4 us.

[Qiaozhi]

The worst jitter is caused by leaving Timer0 interrupts running in the background. These are masked in the setup routine, but does have the side-effect of disabling the software delay functions.

Teleno is most likely correct that the Delay pot is the cause, although I'm a bit surprised that any audio jitter would be that noticeable for a change as small as 62.5ns.

[gallico58]

Thanks Teleno and Qiaozhi, I will try to change the code, I am quite good with the soldering iron but I am denied in software programming.
sorry also my bad english, i use the translator!

[Teleno]

Teleno is most likely correct that the Delay pot is the cause, although I'm a bit surprised that any audio jitter would be that noticeable for a change as small as 62.5ns.

The maximum accuracy of the ADC is 3.5 bits (page 265, table 28.9 of the Atmega328P datasheet). Thus the ADC value can vary by 1.1% from one measurement to the next for the same pot position.
2^3.5 is 11.3, so a jitter of 11.3 x 62.5ns = 706 ns can be expected from this alone.
Then the potentiometer's own jitter on top of it, a well known phenomenon: Potentiometer jitter
The interrupt jitter is about 1 cycle because most of the instructions take 1 or 2 cycles, very rarely 3 or more, and their execution is completed before serving the interrupt.

Thanks Teleno and Qiaozhi, I will try to change the code, I am quite good with the soldering iron but I am denied in software programming.
sorry also my bad english, i use the translator!

Try the hysteresis code first. The new .ino file would be like this:

// Arduino Pulse Induction Metal Detector

// Pin assignments
byte txPin = 8;          // Assign pin 8 to TX output
byte mainSamplePin = 9;  // Assign pin 9 to main sample pulse
byte efeSamplePin = 10;  // Assign pin 10 to EFE sample pulse
byte audioPin = 11;      // Assign pin 11 to audio chopper
byte boostPin = 12;      // Assign pin 12 to boost switch
byte delayPin = A0;      // Assign delay pot to A0


// Program constants
const float normalPower = 50E-6;       // Normal TX-on time (50us)
const float boostPower = 100E-6;       // Boost TX-on time (100us)
const float clockCycle = 62.5E-9;      // Time for one clock cycle (1/16MHz)
const unsigned long maxCount = 65535;  // Value of 2^16 - 1
const byte readDelayLimit = 100;       // Wait 100 TX periods (100ms) before reading delay pot
const byte mosfetOn = HIGH;            // Mosfet turns on when transmitter input high
const byte mosfetOff = LOW;            // Mosfet turns off when transmitter input low
const byte syncDemodOn = LOW;          // Sample gate turns on when input high
const byte syncDemodOff = HIGH;        // Sample gate turns off when input low


// Detector timings
float txOn = normalPower;        // TX-on time using normal power mode
float defMainDelay = 10E-6;      // Default main sample delay (10us)
float mainDelay = defMainDelay;  // Main sample pulse delay
float mainSample = 50E-6;        // Main sample pulse width (50us)
float efeDelay = 240E-6;         // EFE sample pulse delay (240us)
float efeSample = mainSample;    // EFE sample pulse width (same as main sample)
float txPeriod = 1E-3;           // TX period (1ms)


// Timing offsets
float txOnOffset = 3E-6;         // TX-on pulse offset (3us)
float mainDelayOffset = 4.2E-6;  // Main delay pulse offset (4.2us)
float mainSampleOffset = 3E-6;   // Main sample pulse offset (3us)
float efeDelayOffset = 12E-6;    // EFE delay pulse offset (12us)
float efeSampleOffset = 4E-6;    // EFE sample pulse offset (4us)
float txPeriodOffset = 30E-6;    // TX period offset (30us)


// Program variables
float temp1, temp2, temp3, temp4, temp5, temp6;  // Intermediate calculation variables
word txOnCount;                                  // TX pulse
word mainDelayCount;                             // Main sample delay
word mainSampleCount;                            // Main sample pulse
word efeDelayCount;                              // EFE sample delay
word efeSampleCount;                             // EFE sample pulse
word txPeriodCount;                              // TX period
word potValue;                                   // Voltage at the delay pot
word delayVal = 0;                               // Delay pot value
boolean readDelayPot = false;                    // Delay pot read (true or false)
byte intState = 0;                               // Interrupt state machine
byte readDelayCounter = 0;                       // Read delay pot counter


void setup() {
  pinMode(txPin, OUTPUT);           // Set TX pin to output mode
  pinMode(mainSamplePin, OUTPUT);   // Set main sample pin to output mode
  pinMode(efeSamplePin, OUTPUT);    // Set EFE sample pin to output mode
  pinMode(boostPin, INPUT_PULLUP);  // Set Boost switch pin to input mode with pullup resistor
  calcTimerValues();                // Calculate all timer values
  noInterrupts();                   // Disable interrupts
  TCCR1A = 0;                       // Initialize Timer1 registers
  TCCR1B = 0;
  TIMSK0 = 0;                       // Clear Timer0 mask register to eliminate jitter
  TCNT1 = txOnCount;                // Load Timer1 with TX-on count
  TCCR1B |= (1 << CS10);            // No prescaling for Timer1
  TIMSK1 |= (1 << TOIE1);           // Enable Timer1 overflow interrupt
  interrupts();                     // Enable interrupts
  analogWrite(audioPin, 127);       // Set audioPin with 50% duty cycle PWM
}


void calcTimerValues() {
  if (digitalRead(boostPin) == HIGH) {                   // Get boost switch position
    txOn = normalPower;                                  // Set TX-on to 50us if HIGH
  } else {
    txOn = boostPower;                                   // Set TX-on to 100us if LOW
  }
  temp1 = (txOn - txOnOffset) / clockCycle;
  txOnCount = maxCount - int(temp1);                     // TX-on count for Timer1
  temp2 = (mainDelay - mainDelayOffset) / clockCycle;
  mainDelayCount = maxCount - int(temp2);                // Main sample delay count for Timer1
  temp3 = (mainSample - mainSampleOffset) / clockCycle;
  mainSampleCount = maxCount - int(temp3);               // Main sample pulse count for Timer1
  temp4 = (efeDelay - efeDelayOffset) / clockCycle;
  temp4 -= temp3 + temp2;
  efeDelayCount = maxCount - int(temp4);                 // EFE sample delay count for Timer1
  temp5 = (efeSample - efeSampleOffset) / clockCycle;
  efeSampleCount = maxCount - int(temp5);                // EFE sample pulse count for Timer 1
  temp6 = (txPeriod - txPeriodOffset) / clockCycle;
  temp6 -= temp1 + temp2 + temp3 + temp4 + temp5;
  txPeriodCount = maxCount - int(temp6);                 // TX period count for Timer1
}


ISR(TIMER1_OVF_vect) {
  switch (intState) {
    case 0:
      TCNT1 = txOnCount;                           // Load Timer1 with TX-ON count
      digitalWrite(txPin, mosfetOn);               // Turn on Mosfet
      intState = 1;
      break;
    case 1:
      TCNT1 = mainDelayCount;                      // Load Timer1 with main sample delay count
      digitalWrite(txPin, mosfetOff);              // Turn off Mosfet
      intState = 2;
      break;
    case 2:
      TCNT1 = mainSampleCount;                     // Load Timer1 with main sample pulse count
      digitalWrite(mainSamplePin, syncDemodOn);    // Turn on main sample gate
      intState = 3;
      break;
    case 3:
      TCNT1 = efeDelayCount;                       // Load Timer1 with EFE sample delay count
      digitalWrite(mainSamplePin, syncDemodOff);   // Turn off main sample gate
      if (readDelayPot == false) {                 // Check if read delay pot flag is false
        readDelayCounter++;                        // Increment read delay counter
        if (readDelayCounter >= readDelayLimit) {  // Check if read delay counter has reached limit
          readDelayPot = true;                     // Enable read of delay pot
          readDelayCounter = 0;                    // Clear read delay counter
        }
      }
      intState = 4;
      break;
    case 4:
      TCNT1 = efeSampleCount;                      // Load Timer1 with EFE sample pulse count
      digitalWrite(efeSamplePin, syncDemodOn);     // Turn on EFE sample gate
      intState = 5;
      break;
    case 5:
      TCNT1 = txPeriodCount;                       // Load Timer1 with TX period count
      digitalWrite(efeSamplePin, syncDemodOff);    // Turn off EFE sample gate
      intState = 0;
      break;
    default:
      intState = 0;
      break;
  }
}


void loop() {
  if (readDelayPot == true) {
    potRead = analogRead(delayPin);                   // Read the delay pot
    if (potRead > (delayVal + 16)) delayVal = potRead - 16;
    else if (potRead < (delayVal  - 16)) delayVal = potRead + 16;
    mainDelay = defMainDelay + delayVal * clockCycle;  // Offset main sample delay
    calcTimerValues();                                 // Calculate new timer values
    readDelayPot = false;                              // Set read delay pot flag to false
  }
}

[gallico58]

Thanks Teleno, it works well, more stable.
ide was giving me error I had to insert, I hope in the right place the line "word Potread = 0;" this link for a video:

https://drive.google.com/file/d/1cUw...ew?usp=sharing

// Arduino Pulse Induction Metal Detector


// Pin assignments
byte txPin = 8; // Assign pin 8 to TX output
byte mainSamplePin = 9; // Assign pin 9 to main sample pulse
byte efeSamplePin = 10; // Assign pin 10 to EFE sample pulse
byte audioPin = 11; // Assign pin 11 to audio chopper
byte boostPin = 12; // Assign pin 12 to boost switch
byte delayPin = A0; // Assign delay pot to A0




// Program constants
const float normalPower = 50E-6; // Normal TX-on time (50us)
const float boostPower = 100E-6; // Boost TX-on time (100us)
const float clockCycle = 62.5E-9; // Time for one clock cycle (1/16MHz)
const unsigned long maxCount = 65535; // Value of 2^16 - 1
const byte readDelayLimit = 100; // Wait 100 TX periods (100ms) before reading delay pot
const byte mosfetOn = HIGH; // Mosfet turns on when transmitter input high
const byte mosfetOff = LOW; // Mosfet turns off when transmitter input low
const byte syncDemodOn = LOW; // Sample gate turns on when input high
const byte syncDemodOff = HIGH; // Sample gate turns off when input low




// Detector timings
float txOn = normalPower; // TX-on time using normal power mode
float defMainDelay = 10E-6; // Default main sample delay (10us)
float mainDelay = defMainDelay; // Main sample pulse delay
float mainSample = 50E-6; // Main sample pulse width (50us)
float efeDelay = 240E-6; // EFE sample pulse delay (240us)
float efeSample = mainSample; // EFE sample pulse width (same as main sample)
float txPeriod = 1E-3; // TX period (1ms)




// Timing offsets
float txOnOffset = 3E-6; // TX-on pulse offset (3us)
float mainDelayOffset = 4.2E-6; // Main delay pulse offset (4.2us)
float mainSampleOffset = 3E-6; // Main sample pulse offset (3us)
float efeDelayOffset = 12E-6; // EFE delay pulse offset (12us)
float efeSampleOffset = 4E-6; // EFE sample pulse offset (4us)
float txPeriodOffset = 30E-6; // TX period offset (30us)




// Program variables
float temp1, temp2, temp3, temp4, temp5, temp6; // Intermediate calculation variables
word txOnCount; // TX pulse
word mainDelayCount; // Main sample delay
word mainSampleCount; // Main sample pulse
word efeDelayCount; // EFE sample delay
word efeSampleCount; // EFE sample pulse
word txPeriodCount; // TX period
word potRead = 0;
word potValue; // Voltage at the delay pot
word delayVal = 0; // Delay pot value
boolean readDelayPot = false; // Delay pot read (true or false)
byte intState = 0; // Interrupt state machine
byte readDelayCounter = 0; // Read delay pot counter




void setup() {
pinMode(txPin, OUTPUT); // Set TX pin to output mode
pinMode(mainSamplePin, OUTPUT); // Set main sample pin to output mode
pinMode(efeSamplePin, OUTPUT); // Set EFE sample pin to output mode
pinMode(boostPin, INPUT_PULLUP); // Set Boost switch pin to input mode with pullup resistor
calcTimerValues(); // Calculate all timer values
noInterrupts(); // Disable interrupts
TCCR1A = 0; // Initialize Timer1 registers
TCCR1B = 0;
TIMSK0 = 0; // Clear Timer0 mask register to eliminate jitter
TCNT1 = txOnCount; // Load Timer1 with TX-on count
TCCR1B |= (1 << CS10); // No prescaling for Timer1
TIMSK1 |= (1 << TOIE1); // Enable Timer1 overflow interrupt
interrupts(); // Enable interrupts
analogWrite(audioPin, 127); // Set audioPin with 50% duty cycle PWM
}




void calcTimerValues() {
if (digitalRead(boostPin) == HIGH) { // Get boost switch position
txOn = normalPower; // Set TX-on to 50us if HIGH
} else {
txOn = boostPower; // Set TX-on to 100us if LOW
}
temp1 = (txOn - txOnOffset) / clockCycle;
txOnCount = maxCount - int(temp1); // TX-on count for Timer1
temp2 = (mainDelay - mainDelayOffset) / clockCycle;
mainDelayCount = maxCount - int(temp2); // Main sample delay count for Timer1
temp3 = (mainSample - mainSampleOffset) / clockCycle;
mainSampleCount = maxCount - int(temp3); // Main sample pulse count for Timer1
temp4 = (efeDelay - efeDelayOffset) / clockCycle;
temp4 -= temp3 + temp2;
efeDelayCount = maxCount - int(temp4); // EFE sample delay count for Timer1
temp5 = (efeSample - efeSampleOffset) / clockCycle;
efeSampleCount = maxCount - int(temp5); // EFE sample pulse count for Timer 1
temp6 = (txPeriod - txPeriodOffset) / clockCycle;
temp6 -= temp1 + temp2 + temp3 + temp4 + temp5;
txPeriodCount = maxCount - int(temp6); // TX period count for Timer1
}




ISR(TIMER1_OVF_vect) {
switch (intState) {
case 0:
TCNT1 = txOnCount; // Load Timer1 with TX-ON count
digitalWrite(txPin, mosfetOn); // Turn on Mosfet
intState = 1;
break;
case 1:
TCNT1 = mainDelayCount; // Load Timer1 with main sample delay count
digitalWrite(txPin, mosfetOff); // Turn off Mosfet
intState = 2;
break;
case 2:
TCNT1 = mainSampleCount; // Load Timer1 with main sample pulse count
digitalWrite(mainSamplePin, syncDemodOn); // Turn on main sample gate
intState = 3;
break;
case 3:
TCNT1 = efeDelayCount; // Load Timer1 with EFE sample delay count
digitalWrite(mainSamplePin, syncDemodOff); // Turn off main sample gate
if (readDelayPot == false) { // Check if read delay pot flag is false
readDelayCounter++; // Increment read delay counter
if (readDelayCounter >= readDelayLimit) { // Check if read delay counter has reached limit
readDelayPot = true; // Enable read of delay pot
readDelayCounter = 0; // Clear read delay counter
}
}
intState = 4;
break;
case 4:
TCNT1 = efeSampleCount; // Load Timer1 with EFE sample pulse count
digitalWrite(efeSamplePin, syncDemodOn); // Turn on EFE sample gate
intState = 5;
break;
case 5:
TCNT1 = txPeriodCount; // Load Timer1 with TX period count
digitalWrite(efeSamplePin, syncDemodOff); // Turn off EFE sample gate
intState = 0;
break;
default:
intState = 0;
break;
}
}




void loop() {
if (readDelayPot == true) {
potRead = analogRead(delayPin); // Read the delay pot
if (potRead > (delayVal + 16)) delayVal = potRead - 16;
else if (potRead < (delayVal - 16)) delayVal = potRead + 16;
mainDelay = defMainDelay + delayVal * clockCycle; // Offset main sample delay
calcTimerValues(); // Calculate new timer values
readDelayPot = false; // Set read delay pot flag to false
}
}

[Teleno]

Thanks Teleno, it works well, more stable.
ide was giving me error I had to insert, I hope in the right place the line "word Potread = 0;" this link for a video:

https://drive.google.com/file/d/1cUw...ew?usp=sharing

Good to hear.

I made the error of inserting "word potValue" where I should have written "word potRead".

Corrected program:

// Arduino Pulse Induction Metal Detector

// Pin assignments
byte txPin = 8;          // Assign pin 8 to TX output
byte mainSamplePin = 9;  // Assign pin 9 to main sample pulse
byte efeSamplePin = 10;  // Assign pin 10 to EFE sample pulse
byte audioPin = 11;      // Assign pin 11 to audio chopper
byte boostPin = 12;      // Assign pin 12 to boost switch
byte delayPin = A0;      // Assign delay pot to A0


// Program constants
const float normalPower = 50E-6;       // Normal TX-on time (50us)
const float boostPower = 100E-6;       // Boost TX-on time (100us)
const float clockCycle = 62.5E-9;      // Time for one clock cycle (1/16MHz)
const unsigned long maxCount = 65535;  // Value of 2^16 - 1
const byte readDelayLimit = 100;       // Wait 100 TX periods (100ms) before reading delay pot
const byte mosfetOn = HIGH;            // Mosfet turns on when transmitter input high
const byte mosfetOff = LOW;            // Mosfet turns off when transmitter input low
const byte syncDemodOn = LOW;          // Sample gate turns on when input high
const byte syncDemodOff = HIGH;        // Sample gate turns off when input low


// Detector timings
float txOn = normalPower;        // TX-on time using normal power mode
float defMainDelay = 10E-6;      // Default main sample delay (10us)
float mainDelay = defMainDelay;  // Main sample pulse delay
float mainSample = 50E-6;        // Main sample pulse width (50us)
float efeDelay = 240E-6;         // EFE sample pulse delay (240us)
float efeSample = mainSample;    // EFE sample pulse width (same as main sample)
float txPeriod = 1E-3;           // TX period (1ms)


// Timing offsets
float txOnOffset = 3E-6;         // TX-on pulse offset (3us)
float mainDelayOffset = 4.2E-6;  // Main delay pulse offset (4.2us)
float mainSampleOffset = 3E-6;   // Main sample pulse offset (3us)
float efeDelayOffset = 12E-6;    // EFE delay pulse offset (12us)
float efeSampleOffset = 4E-6;    // EFE sample pulse offset (4us)
float txPeriodOffset = 30E-6;    // TX period offset (30us)


// Program variables
float temp1, temp2, temp3, temp4, temp5, temp6;  // Intermediate calculation variables
word txOnCount;                                  // TX pulse
word mainDelayCount;                             // Main sample delay
word mainSampleCount;                            // Main sample pulse
word efeDelayCount;                              // EFE sample delay
word efeSampleCount;                             // EFE sample pulse
word txPeriodCount;                              // TX period
word potRead;                                    // Voltage at the delay pot
word delayVal = 0;                               // Delay pot value
boolean readDelayPot = false;                    // Delay pot read (true or false)
byte intState = 0;                               // Interrupt state machine
byte readDelayCounter = 0;                       // Read delay pot counter


void setup() {
  pinMode(txPin, OUTPUT);           // Set TX pin to output mode
  pinMode(mainSamplePin, OUTPUT);   // Set main sample pin to output mode
  pinMode(efeSamplePin, OUTPUT);    // Set EFE sample pin to output mode
  pinMode(boostPin, INPUT_PULLUP);  // Set Boost switch pin to input mode with pullup resistor
  calcTimerValues();                // Calculate all timer values
  noInterrupts();                   // Disable interrupts
  TCCR1A = 0;                       // Initialize Timer1 registers
  TCCR1B = 0;
  TIMSK0 = 0;                       // Clear Timer0 mask register to eliminate jitter
  TCNT1 = txOnCount;                // Load Timer1 with TX-on count
  TCCR1B |= (1 << CS10);            // No prescaling for Timer1
  TIMSK1 |= (1 << TOIE1);           // Enable Timer1 overflow interrupt
  interrupts();                     // Enable interrupts
  analogWrite(audioPin, 127);       // Set audioPin with 50% duty cycle PWM
}


void calcTimerValues() {
  if (digitalRead(boostPin) == HIGH) {                   // Get boost switch position
    txOn = normalPower;                                  // Set TX-on to 50us if HIGH
  } else {
    txOn = boostPower;                                   // Set TX-on to 100us if LOW
  }
  temp1 = (txOn - txOnOffset) / clockCycle;
  txOnCount = maxCount - int(temp1);                     // TX-on count for Timer1
  temp2 = (mainDelay - mainDelayOffset) / clockCycle;
  mainDelayCount = maxCount - int(temp2);                // Main sample delay count for Timer1
  temp3 = (mainSample - mainSampleOffset) / clockCycle;
  mainSampleCount = maxCount - int(temp3);               // Main sample pulse count for Timer1
  temp4 = (efeDelay - efeDelayOffset) / clockCycle;
  temp4 -= temp3 + temp2;
  efeDelayCount = maxCount - int(temp4);                 // EFE sample delay count for Timer1
  temp5 = (efeSample - efeSampleOffset) / clockCycle;
  efeSampleCount = maxCount - int(temp5);                // EFE sample pulse count for Timer 1
  temp6 = (txPeriod - txPeriodOffset) / clockCycle;
  temp6 -= temp1 + temp2 + temp3 + temp4 + temp5;
  txPeriodCount = maxCount - int(temp6);                 // TX period count for Timer1
}


ISR(TIMER1_OVF_vect) {
  switch (intState) {
    case 0:
      TCNT1 = txOnCount;                           // Load Timer1 with TX-ON count
      digitalWrite(txPin, mosfetOn);               // Turn on Mosfet
      intState = 1;
      break;
    case 1:
      TCNT1 = mainDelayCount;                      // Load Timer1 with main sample delay count
      digitalWrite(txPin, mosfetOff);              // Turn off Mosfet
      intState = 2;
      break;
    case 2:
      TCNT1 = mainSampleCount;                     // Load Timer1 with main sample pulse count
      digitalWrite(mainSamplePin, syncDemodOn);    // Turn on main sample gate
      intState = 3;
      break;
    case 3:
      TCNT1 = efeDelayCount;                       // Load Timer1 with EFE sample delay count
      digitalWrite(mainSamplePin, syncDemodOff);   // Turn off main sample gate
      if (readDelayPot == false) {                 // Check if read delay pot flag is false
        readDelayCounter++;                        // Increment read delay counter
        if (readDelayCounter >= readDelayLimit) {  // Check if read delay counter has reached limit
          readDelayPot = true;                     // Enable read of delay pot
          readDelayCounter = 0;                    // Clear read delay counter
        }
      }
      intState = 4;
      break;
    case 4:
      TCNT1 = efeSampleCount;                      // Load Timer1 with EFE sample pulse count
      digitalWrite(efeSamplePin, syncDemodOn);     // Turn on EFE sample gate
      intState = 5;
      break;
    case 5:
      TCNT1 = txPeriodCount;                       // Load Timer1 with TX period count
      digitalWrite(efeSamplePin, syncDemodOff);    // Turn off EFE sample gate
      intState = 0;
      break;
    default:
      intState = 0;
      break;
  }
}


void loop() {
  if (readDelayPot == true) {
    potRead = analogRead(delayPin);                        // Read the delay pot
    /* update delayVal with hysteresis to avoid ADC and pot jitter */                       
    if (potRead > (delayVal + 16)) delayVal = potRead - 16;
    else if (potRead < (delayVal  - 16)) delayVal = potRead + 16;
    mainDelay = defMainDelay + delayVal * clockCycle;      // Offset main sample delay
    calcTimerValues();                                     // Calculate new timer values
    readDelayPot = false;                                  // Set read delay pot flag to false
  }
}

[Qiaozhi]

Thanks Teleno and gallico58.

I'll load the modified code tonight and compare the difference.
Personally I'm really pleased with the way the Arduino Nano PI has turned out. It's a great platform for learning about the Arduino, and provides a lot of flexibility for further experiments.

[Qiaozhi]

I first tested the original code in the ANPI, and there was a small amount of jitter on the main sample delay, probably less than 100ns.
Then I tested Teleno's code and the sample delay was rock solid.

However, there was no discernible difference in performance between the two versions as far as the audio response was concerned. I suspect this is because any small jitter is being integrated out in the following stages.

There was one side-effect of adding hysteresis to the sample delay pot measurement though. I discovered that it was possible to adjust the pot to a position where it caused a repeating beep in the audio output, and the sample delay (on the scope) jumped around between two settings.

The adjustment of the sample delay was also much smoother in the original version.

Maybe a running average would be a better solution if you're concerned about the jitter.

[gallico58]

Hi George, however it may be a subjective problem, it may be that my construction on a breadboard is not so perfect, I would leave everything as an original from a book that works well, maybe opening a dedicated post on modifications would be more appropriate, what do you think?
however the audio and oscilloscope pulses in a certain position of the potentiometer you describe were really my problem, perhaps I had not explained myself well.
but when I replaced the code with that of Teleno they practically disappeared ........ Mystery!

[Qiaozhi]

Amazon have announced that paperback printing will begin launching in Australia on May 19, 2021.

No longer will our Australian friends have to order books via the USA, or at inflated prices from third-party book sellers.

[MartyJ1963]

Hi everyone. I'm having a real difficult time with my new Arduino Nano V.3 boards. The first 2 Nano's I ordered had the ch340g chip on board and I couldn't zero the 5534 or get the -5v on the both ANPI's I built. I received my 2 x Nano boards today that have the FT232R UART Chip on board and cannot get my pc to recognise them or install drivers for them. I have downloaded original drivers from FTI etc and other sites and still can't get the pc to recognise it or install it correctly. It's driving me absolutely daft! as I've been at this now for weeks! Can anyone offer any suggestions or alternative drivers or procedures etc please? Thanks, Marty.